#!/usr/bin/perl -w
#  $Id: probe 18145 2010-04-01 01:13:50Z teetov $
# -----------------------------------------------------------------------------
#  Purpose:
#    - probe the camera
#    - pre-tune camera befor for retriever (RC and Audio)
# -----------------------------------------------------------------------------
#  Call:
#    probe DEVID=123   
#    probe DEVID=123 PROBE=FAST  
#    probe DEVID=123 DEVIP=192.168.17.177 [ ... ]
#    probe DEVIP=192.168.17.177 USRNAME=admin PASSWD=pass PROBE=DEFINE
# -----------------------------------------------------------------------------
#  Does:
#   0. can be called without DEVID argument. 
#      In this case DEVIP,USRNAME,PASSWD should be provided in command line
#   1. load $APL_CONF/<DEVID>/conf if DEVID is provided
#   2. combine conf and args into one hash
#   3. connect to camera over http and read MODELID and FIRMWARE
#   4. report MODELID|FIRMWARE|STATUS to $APL_CONF/<DEVID>/conf.probe and stdout
#   5. if PROBE=DEFINE then get
#         IMAGESIZE_LIST,MEDIA_FORMAT_LIST
#         AUDIO_LIST,AUDIO_FORMAT_LIST
#         SNAPSHOT (picture)
#   6. set RC camera attributes    if mpeg4 | h264
#   7. set AUDIO camera attributes if AUDIO is on 
#   8. example output:
#       AUDIO_SET=OK
#       FIRMWARE=5.02
#       MODELID=Q1755
#       RC_SET=OK
#       STATUS=OK
#       -------------
#       AUDIO_SET=NONE
#       FIRMWARE=5.02
#       MODELID=Q1755
#       RC_SET=NONE
#       STATUS=OK
#       SNAPSHOT=/tmp/probe/192.168.17.177-12367576123.jpg
#       IMAGESIZE_LIST=640x480,480x360,320x240,240x180,176x144,160x120
#       MEDIA_FORMAT_LIST=mjpeg,h264
#       AUDIO_LIST=off,on
#       AUDIO_FORMAT_LIST=g711,g726,aac
#   9. sample errors: 
#       STATUS=ERROR: PCE-0001 [101] configuration is not found
#       STATUS=ERROR: PCE-0002 [101] USRNAME and PASSWD should provided
#       STATUS=ERROR: PCE-0003 [101] DEVIP is not defined
#       STATUS=ERROR: PCE-0500 [101] Device does not respond (http://207.107.163.123:80)
#       STATUS=ERROR: PCE-0401 [101] Authorization error 
#       STATUS=ERROR: PCE-0403 [101] Forbidden 
#       STATUS=ERROR: PCE-0030 [101] Cannot get MODELID
#       note: [101] is DEVID
#  10. warnings:
#       STATUS=WARNING: PCW-0001 [101] MODELID does not match configuration
#       STATUS=WARNING: PCW-0002 [101] FIRMWARE does not match configuration
#       STATUS=WARNING: PCW-0009 [101] PROBE=RESET is not supported
#       
# -----------------------------------------------------------------------------
#  Note:
#   1. CAMERAMODEL file is obsolite. ptz_axisv2.pl & ptz_udp.pl has to be modified
#   2. Script mast be in the directory .../camera/<BRAND>/bin/
# -----------------------------------------------------------------------------
#  Author: teetov, 03/22/10
#  Edited by:
#  QA by:
#  Copyright: videoNEXT Network Solutions, Inc, 2010

use strict;
use Device::Conf;

# --------- check required parameters: DEVID,USRNAME,PASSWD,
my $conf=ProbeInit(7);  # uses <BRAND> from path and ARGV
ProbeErr("PCE-0001","configuration is not found") if not defined $conf->{DEVID}; 
ProbeErr("PCE-0003","DEVIP is not defined")       if not defined $conf->{DEVIP};
ProbeErr("PCE-0002","USRNAME and PASSWD should be provided") 
                 if not defined $conf->{USRNAME} or not defined $conf->{PASSWD};
ProbeWarn("PCW-0009","PROBE=RESET is not supported") if $conf->{PROBE} eq 'RESET';
# -- Probe camera MODELID & FIRMWARE --
my %params;
my %result = (MODELID=>'0',FIRMWARE=>'0.0',STATUS=>'OK',RC_SET=>'NONE',AUDIO_SET=>'NONE');
my $rsp = ProbeRequest("/cgi-bin/admin/getparam.cgi?system_info_modelname&system_info_firmwareversion&capability_videoin_codec");

if ($rsp !~ /^HTTP ERROR/) {
     %params = map { $_ =~ /^(.+)='(.*)'$/ }  split /\r?\n/, $rsp;
     $result{MODELID} = $params{'system_info_modelname'};
     $result{FIRMWARE} = $params{'system_info_firmwareversion'};
} else {
    my ($err)= $rsp =~ /^HTTP ERROR \[(\d+)\]/;
    ProbeErr("PCE-0500","Device does not respond",$rsp) if $err=~/^5\d\d/;
    ProbeErr("PCE-0401","Authorization error",    $rsp) if $err==401;
}

ProbeErr("PCE-0030","Cannot get MODELID or FIRMWARE",$rsp) unless $result{MODELID};

# -- Check MODELID & FIRMWARE --
if(defined $conf->{MODELID} and $result{MODELID} ne $conf->{MODELID}) {
  $result{STATUS}="WARNING: PCW-0001 [$conf->{DEVID}] MODELID does not match configuration";
}elsif(defined $conf->{CAMERAFIRMWARE} and $result{FIRMWARE} ne $conf->{CAMERAFIRMWARE}) {
  $result{STATUS}="WARNING: PCW-0001 [$conf->{DEVID}] FIRMWARE does not match configuration";
}

my %norm_mfl = map {(NormMediaFormat($_),$_)} split /,/ , $params{'capability_videoin_codec'};

if ($conf->{PROBE} eq 'DEFINE') {
    $rsp = ProbeRequest("/cgi-bin/admin/getparam.cgi?capability_videoin_resolution&capability_nmediastream&capability_audioin_codec&capability_audio_lineout");
    if ($rsp !~ /^HTTP ERROR/) {
	%params = map { $_ =~ /^(.+)='(.*)'$/ }  split /\r?\n/, $rsp;
    } else {
	my ($err)= $rsp =~ /^HTTP ERROR \[(\d+)\]/;
	ProbeErr("PCE-0500","Device does not respond",$rsp) if $err=~/^5\d\d/;
	ProbeErr("PCE-0401","Authorization error",    $rsp) if $err==401;
    }
    my @isl;
    if ($result{MODELID} eq 'FD8361') {
	@isl = ('176x144\,320x240\,640x480\,800x600\,1280x960\,1600x1200',
	    	'176x144\,320x240\,640x480\,800x600',
		'176x144',
		'176x144\,320x240\,640x480\,800x600\,1280x960\,1600x1200'
	);
    } else {
	my $resol = $params{'capability_videoin_resolution'};
	$resol =~ s/\s*,\s*/\\,/g; 
	for (my $i = 0; $i < $params{'capability_nmediastream'}; ++$i) {
	    $isl[$i] = $resol;
	}
    }

    for (my $i = 0; $i < $params{'capability_nmediastream'}; ++$i) {
	$result{CAMERA_LIST} .= "$i,";
	$result{SNAPSHOT_LIST} .= "$i:".ProbeSamplePicture({CAMERA=>$i}).",";
	$result{IMAGESIZE_LIST} .= "$i:".$isl[$i].",";
    }
    chop($result{CAMERA_LIST});
    chop($result{SNAPSHOT_LIST});
    chop($result{IMAGESIZE_LIST});
    $result{MEDIA_FORMAT_LIST} .= "$_," foreach(keys %norm_mfl);
    chop($result{MEDIA_FORMAT_LIST});
    $result{AUDIO_FORMAT_LIST} = $params{'capability_audioin_codec'};
    $result{AUDIO_LIST} = 'off,on' if $params{'capability_audio_lineout'} eq '1';
}

# -- interim report & exit --
ProbeResult(\%result)  if $conf->{PROBE} =~ /^(DEFINE|FAST)$/;
ProbeResult(\%result)  if $conf->{DEVID} =~ /^a/; # define only if audio device
ProbeResult(\%result)  if $conf->{DEVID} == 0;


# -- set RC (rate control) parameters + qality + imagesize --
my $cmf = $norm_mfl{$conf->{MEDIA_FORMAT}};
my $camera = defined($conf->{CAMERA}) ? $conf->{CAMERA} : '0';
my $req = "/cgi-bin/admin/setparam.cgi";
$req .= "?videoin_c0_s${camera}_codectype=".$cmf;
$req .= "&videoin_c0_s${camera}_resolution=".$conf->{IMAGESIZE} if defined($conf->{IMAGESIZE});
$req .= "&videoin_c0_s${camera}_".$cmf."_maxframe=".$conf->{FRAMERATE} if defined($conf->{FRAMERATE});
$req .= "&videoin_c0_s${camera}_".$cmf."_intraperiod=".$conf->{INTRAFRAME} if defined($conf->{INTRAFRAME}); 
$req .= "&videoin_c0_s${camera}_".$cmf."_ratecontrolmode=".$conf->{RC_MODE} if defined($conf->{RC_MODE}); 
if ($conf->{RC_MODE} eq 'cbr') {
    $req .= "&videoin_c0_s${camera}_".$cmf."_bitrate=".$conf->{RC_TARGETBITRATE} if defined($conf->{RC_TARGETBITRATE}); 
} else {
    $req .= "&videoin_c0_s${camera}_".$cmf."_quant=".$conf->{CAMCOMPRESSION} if defined($conf->{CAMCOMPRESSION}); 
}

# -- set AudioParams --
if ($conf->{AUDIO} eq 'on') {
    $req .= "&audioin_c0_mute=0&audioin_c0_s0_codectype=aac4";
} else {
    $req .= "&audioin_c0_mute=1";
}

$rsp = ProbeRequest($req);

if ($rsp !~ /^HTTP ERROR/) {
    $result{RC_SET} = 'OK';
    $result{AUDIO_SET} = 'OK';
} else {
    my ($err)= $rsp =~ /^HTTP ERROR \[(\d+)\]/;
    ProbeErr("PCE-0500","Device does not respond",$rsp) if $err=~/^5\d\d/;
    ProbeErr("PCE-0401","Authorization error",    $rsp) if $err==401;
}



# -- final report --
$rsp = ProbeRequest("/cgi-bin/admin/getparam.cgi?network_http_s${camera}_accessname&network_rtsp_s${camera}_accessname");
if ($rsp !~ /^HTTP ERROR/) {
    %params = map { $_ =~ /^(.+)='(.*)'$/ }  split /\r?\n/, $rsp;
} else {
    my ($err)= $rsp =~ /^HTTP ERROR \[(\d+)\]/;
    ProbeErr("PCE-0500","Device does not respond",$rsp) if $err=~/^5\d\d/;
    ProbeErr("PCE-0401","Authorization error",    $rsp) if $err==401;
}

$result{MJPG_HTTP_URL} = $params{"network_http_s${camera}_accessname"};
$result{MPEG4_RTSP_URL} = $params{"network_rtsp_s${camera}_accessname"};
$result{H264_RTSP_URL} = $params{"network_rtsp_s${camera}_accessname"};
ProbeResult(\%result);
