#!/usr/bin/perl -w
#  $Id: probe 18145 2010-04-01 01:13:50Z teetov $
# -----------------------------------------------------------------------------
#  Purpose:
#    - probe the camera
#    - pre-tune camera befor for retriever (RC and Audio)
# -----------------------------------------------------------------------------
#  Call:
#    probe DEVID=123   
#    probe DEVID=123 PROBE=FAST  
#    probe DEVID=123 DEVIP=192.168.17.177 [ ... ]
#    probe DEVIP=192.168.17.177 USRNAME=admin PASSWD=pass PROBE=DEFINE
# -----------------------------------------------------------------------------
#  Does:
#   0. can be called without DEVID argument. 
#      In this case DEVIP,USRNAME,PASSWD should be provided in command line
#   1. load $APL_CONF/<DEVID>/conf if DEVID is provided
#   2. combine conf and args into one hash
#   3. connect to camera over http and read MODELID and FIRMWARE
#   4. report MODELID|FIRMWARE|STATUS to $APL_CONF/<DEVID>/conf.probe and stdout
#   5. if PROBE=DEFINE then get
#         IMAGESIZE_LIST,MEDIA_FORMAT_LIST
#         AUDIO_LIST,AUDIO_FORMAT_LIST
#         SNAPSHOT (picture)
#   6. set RC camera attributes    if mpeg4 | h264
#   7. set AUDIO camera attributes if AUDIO is on 
#   8. example output:
#       AUDIO_SET=OK
#       FIRMWARE=5.02
#       MODELID=Q1755
#       RC_SET=OK
#       STATUS=OK
#       -------------
#       AUDIO_SET=NONE
#       FIRMWARE=5.02
#       MODELID=Q1755
#       RC_SET=NONE
#       STATUS=OK
#       SNAPSHOT=/tmp/probe/192.168.17.177-12367576123.jpg
#       IMAGESIZE_LIST=640x480,480x360,320x240,240x180,176x144,160x120
#       MEDIA_FORMAT_LIST=mjpeg,h264
#       AUDIO_LIST=off,on
#       AUDIO_FORMAT_LIST=g711,g726,aac
#   9. sample errors: 
#       STATUS=ERROR: PCE-0001 [101] configuration is not found
#       STATUS=ERROR: PCE-0002 [101] USRNAME and PASSWD should provided
#       STATUS=ERROR: PCE-0003 [101] DEVIP is not defined
#       STATUS=ERROR: PCE-0500 [101] Device does not respond (http://207.107.163.123:80)
#       STATUS=ERROR: PCE-0401 [101] Authorization error 
#       STATUS=ERROR: PCE-0403 [101] Forbidden 
#       STATUS=ERROR: PCE-0030 [101] Cannot get MODELID
#       note: [101] is DEVID
#  10. warnings:
#       STATUS=WARNING: PCW-0001 [101] MODELID does not match configuration
#       STATUS=WARNING: PCW-0002 [101] FIRMWARE does not match configuration
#       STATUS=WARNING: PCW-0009 [101] PROBE=RESET is not supported
#       
# -----------------------------------------------------------------------------
#  Note:
#   1. CAMERAMODEL file is obsolite. ptz_axisv2.pl & ptz_udp.pl has to be modified
#   2. Script mast be in the directory .../camera/<BRAND>/bin/
# -----------------------------------------------------------------------------
#  Author: teetov, 03/22/10
#  Edited by:
#  QA by:
#  Copyright: videoNEXT Network Solutions, Inc, 2010
# -----------------------------------------------------------------------------
#
use strict;
use Device::Conf;
#use Data::Dumper;
# cons -------------------------------------------------------------------------
# no code for Xview

# --------- check required parameters: DEVID,USRNAME,PASSWD,
my $conf=ProbeInit();  # uses <BRAND> from path and ARGV
ProbeErr("PCE-0001","configuration is not found") if not defined $conf->{DEVID}; 
ProbeErr("PCE-0003","DEVIP is not defined")       if not defined $conf->{DEVIP};
ProbeErr("PCE-0002","USRNAME and PASSWD should be provided") 
                 if not defined $conf->{USRNAME} or not defined $conf->{PASSWD};
ProbeWarn("PCW-0009","PROBE=RESET is not supported") if $conf->{PROBE} eq 'RESET';
#------------------------------------------------------------------------------
# Probe camera MODELID & FIRMWARE 
#------------------------------------------------------------------------------
my %params;
my %result=(MODELID=>'0',FIRMWARE=>'0.0',STATUS=>'OK',RC_SET=>'NONE',AUDIO_SET=>'NONE');

my $respond =ProbeRequest("/moxa-cgi/systeminfo.cgi");
if($respond!~ /^HTTP ERROR/) {
  %params = map { $_ =~ /^(.*)=(.*)$/ } split /\r?\n/, $respond;
  $result{FIRMWARE} = $params{'FirmwareVersion'};
  $result{MODELID} = $params{'Model'};
}else {
  my ($err)= $respond=~/^HTTP ERROR \[(\d+)\]/;
  ProbeErr("PCE-0500","Device does not respond",$respond) if $err=~/^5\d\d/;
  ProbeErr("PCE-0401","Authorization error",    $respond) if $err==401;
  ProbeErr("PCE-0030","Cannot get MODELID or FIRMWARE",$respond) if ! $result{MODELID};
}
#ProbeErr("PCE-0030","Cannot get MODELID or FIRMWARE",$respond) if ! $result{MODELID};

# Check MODELID & FIRMWARE ---------------------------------------------------
if(defined $conf->{MODELID} and $result{MODELID} ne $conf->{MODELID}) {
  $result{STATUS}="WARNING: PCW-0001 [$conf->{DEVID}] MODELID does not match configuration";
}elsif(defined $conf->{CAMERAFIRMWARE} and $result{FIRMWARE} ne $conf->{CAMERAFIRMWARE}) {
  $result{STATUS}="WARNING: PCW-0001 [$conf->{DEVID}] FIRMWARE does not match configuration";
}


#------------------------------------------------------------------------------
# get Sample picture 
#------------------------------------------------------------------------------
if($conf->{PROBE} eq 'DEFINE') {
   $result{SNAPSHOT}=ProbeSamplePicture();
}

#------------------------------------------------------------------------------
# get video and audio properties
#------------------------------------------------------------------------------

if (defined $params{'VideoCodec'}) {
    my %norm_mfl = map {(NormMediaFormat($_),$_)} split /,/ , $params{'VideoCodec'};

    $result{MEDIA_FORMAT_LIST} .= "$_," foreach(keys %norm_mfl);
    chop($result{MEDIA_FORMAT_LIST});
}

#------------------------------------------------------------------------------
# interim report & exit 
#------------------------------------------------------------------------------
ProbeResult(\%result)  if $conf->{PROBE} =~ /^(DEFINE|FAST)$/;
ProbeResult(\%result)  if $conf->{DEVID}==0;

#------------------------------------------------------------------------------
# set RC (rate control) parameters + qality + imagesize
#------------------------------------------------------------------------------
my $cmf = $conf->{MEDIA_FORMAT};
my $camera = defined($conf->{CAMERA}) ? $conf->{CAMERA} : '1';
my $req;

if ($conf->{MODELID} =~ /364/) {
	$req = "/moxa-cgi/setparam.cgi?video_enable0".$camera."_".$cmf."=1";
	$req .= "&video0$camera"."_size01"."_$cmf=".$conf->{IMAGESIZE} if defined($conf->{IMAGESIZE});
	$req .= "&video0$camera"."_maxframe01"."_$cmf=".$conf->{FRAMERATE} if defined($conf->{FRAMERATE});
	$req .= "&video0$camera"."_quality01"."_$cmf=".$conf->{RC_MODE} if defined($conf->{RC_MODE});
	$req .= "&video0$camera"."_bitrate01"."_$cmf=".$conf->{RC_BITRATE} if defined($conf->{RC_BITRATE});
	$req .= "&video0$camera"."_quant01"."_$cmf=".$conf->{RC_QUAL} if defined($conf->{RC_QUAL});
}elsif($conf->{MODELID} =~ /254|VPM7304|354/i) {
	$req = "/moxa-cgi/setparam.cgi?video0$camera"."_enable=1";
	if($conf->{MODELID} =~ /354/){
		$req .= "&video0$camera"."_size=".$conf->{IMAGESIZE} if defined($conf->{IMAGESIZE});
	}else{
		$req .= "&video0$camera"."_Size=".$conf->{IMAGESIZE} if defined($conf->{IMAGESIZE});
	}
	$req .= "&video0$camera"."_maxframe=".$conf->{FRAMERATE} if defined($conf->{FRAMERATE});
	$req .= "&video0$camera"."_quality=".$conf->{RC_MODE} if defined($conf->{RC_MODE});
	$req .= "&video0$camera"."_bitrate=".$conf->{RC_BITRATE} if defined($conf->{RC_BITRATE});
	$req .= "&video0$camera"."_quant=".$conf->{RC_QUAL} if defined($conf->{RC_QUAL});
	
}elsif($conf->{MODELID} =~ /451|461/){
	$camera = 2 if ($cmf =~ /mjpg/i); # on single-port encoders, channel 2 is always mjpg stream
	$req = "/moxa-cgi/setparam.cgi?video_enable0".$camera."_".$cmf."=1";
	$req .= "&video_size0$camera"."_$cmf=".$conf->{IMAGESIZE} if defined($conf->{IMAGESIZE});
	$req .= "&video_maxframe0$camera"."_$cmf=".$conf->{FRAMERATE} if defined($conf->{FRAMERATE});
	$req .= "&video_quality0$camera"."_$cmf=".$conf->{RC_MODE} if defined($conf->{RC_MODE});
	$req .= "&video_bitrate0$camera"."_$cmf=".$conf->{RC_BITRATE} if defined($conf->{RC_BITRATE});
	$req .= "&video_quant0$camera"."_$cmf=".$conf->{RC_QUAL} if defined($conf->{RC_QUAL});
}else{ # cameras 251/351
	$req = "/moxa-cgi/setparam.cgi?";
	$req .= "video_size"."_$cmf=".$conf->{IMAGESIZE} if defined($conf->{IMAGESIZE});
	$req .= "&video_maxframe"."_$cmf=".$conf->{FRAMERATE} if defined($conf->{FRAMERATE});
	$req .= "&video_quality"."_$cmf=".$conf->{RC_MODE} if defined($conf->{RC_MODE});
	$req .= "&video_bitrate"."_$cmf=".$conf->{RC_BITRATE} if defined($conf->{RC_BITRATE});
	$req .= "&video_quant"."_$cmf=".$conf->{RC_QUAL} if defined($conf->{RC_QUAL});
}

#------------------------------------------------------------------------------
# set AudioParams
#------------------------------------------------------------------------------
if ( $conf->{AUDIO} eq 'on' ) { 
# not impemented yet
}

#----------
# Set params
#----------

my $rsp = ProbeRequest($req);

if ($rsp !~/^HTTP ERROR/) {
	$result{RC_SET} = 'OK';
	$result{AUDIO_SET} = 'OK';
}else {
	my ($err) = $rsp =~ /^HTTP ERROR \[(\d+)\]/;
	ProbeErr("PCE-0500","Device does not respond",$rsp) if $err=~/^5\d\d/;
	ProbeErr("PCE-0401","Authorization error",$rsp) if $err==401;
}


# final report-----------------------------------------------------------------------
ProbeResult(\%result);

