#!/usr/bin/perl -w
#  $Id: probe 18145 2010-04-01 01:13:50Z teetov $
# -----------------------------------------------------------------------------
#  Purpose:
#    - probe the camera
#    - pre-tune camera befor for retriever (RC and Audio)
# -----------------------------------------------------------------------------
#  Call:
#    probe DEVID=123   
#    probe DEVID=123 PROBE=FAST  
#    probe DEVID=123 DEVIP=192.168.17.177 [ ... ]
#    probe DEVIP=192.168.17.177 USRNAME=admin PASSWD=pass PROBE=DEFINE
# -----------------------------------------------------------------------------
#  Does:
#   0. can be called without DEVID argument. 
#      In this case DEVIP,USRNAME,PASSWD should be provided in command line
#   1. load $APL_CONF/<DEVID>/conf if DEVID is provided
#   2. combine conf and args into one hash
#   3. connect to camera over http and read MODELID and FIRMWARE
#   4. report MODELID|FIRMWARE|STATUS to $APL_CONF/<DEVID>/conf.probe and stdout
#   5. if PROBE=DEFINE then get
#         IMAGESIZE_LIST,MEDIA_FORMAT_LIST
#         AUDIO_LIST,AUDIO_FORMAT_LIST
#         SNAPSHOT (picture)
#   6. set RC camera attributes    if mpeg4 | h264
#   7. set AUDIO camera attributes if AUDIO is on 
#   8. example output:
#       AUDIO_SET=OK
#       FIRMWARE=5.02
#       MODELID=Q1755
#       RC_SET=OK
#       STATUS=OK
#       -------------
#       AUDIO_SET=NONE
#       FIRMWARE=5.02
#       MODELID=Q1755
#       RC_SET=NONE
#       STATUS=OK
#       SNAPSHOT=/tmp/probe/192.168.17.177-12367576123.jpg
#       IMAGESIZE_LIST=640x480,480x360,320x240,240x180,176x144,160x120
#       MEDIA_FORMAT_LIST=mjpeg,h264
#       AUDIO_LIST=off,on
#       AUDIO_FORMAT_LIST=g711,g726,aac
#   9. sample errors: 
#       STATUS=ERROR: PCE-0001 [101] configuration is not found
#       STATUS=ERROR: PCE-0002 [101] USRNAME and PASSWD should provided
#       STATUS=ERROR: PCE-0003 [101] DEVIP is not defined
#       STATUS=ERROR: PCE-0500 [101] Device does not respond (http://207.107.163.123:80)
#       STATUS=ERROR: PCE-0401 [101] Authorization error 
#       STATUS=ERROR: PCE-0403 [101] Forbidden 
#       STATUS=ERROR: PCE-0030 [101] Cannot get MODELID
#       note: [101] is DEVID
#  10. warnings:
#       STATUS=WARNING: PCW-0001 [101] MODELID does not match configuration
#       STATUS=WARNING: PCW-0002 [101] FIRMWARE does not match configuration
#       STATUS=WARNING: PCW-0009 [101] PROBE=RESET is not supported
#       
# -----------------------------------------------------------------------------
#  Note:
#   1. CAMERAMODEL file is obsolite. ptz_axisv2.pl & ptz_udp.pl has to be modified
#   2. Script mast be in the directory .../camera/<BRAND>/bin/
# -----------------------------------------------------------------------------
#  Author: teetov, 03/22/10
#  Edited by:
#  QA by:
#  Copyright: videoNEXT Network Solutions, Inc, 2010
# -----------------------------------------------------------------------------
#
use strict;
use Device::Conf ":all";
use XML::Simple;
#use Data::Dumper;
# cons -------------------------------------------------------------------------
# no code for MangoDSP

# --------- check required parameters: DEVID,USRNAME,PASSWD,
my $conf=ProbeInit();  # uses <BRAND> from path and ARGV
ProbeErr("PCE-0001","configuration is not found") if not defined $conf->{DEVID}; 
ProbeErr("PCE-0003","DEVIP is not defined")       if not defined $conf->{DEVIP};
ProbeErr("PCE-0002","USRNAME and PASSWD should be provided") 
                 if not defined $conf->{USRNAME} or not defined $conf->{PASSWD};
ProbeWarn("PCW-0009","PROBE=RESET is not supported") if $conf->{PROBE} eq 'RESET';
#------------------------------------------------------------------------------
# Probe camera MODELID & FIRMWARE 
#------------------------------------------------------------------------------
my %result=(MODELID=>'0',FIRMWARE=>'0.0',STATUS=>'OK',RC_SET=>'NONE',AUDIO_SET=>'NONE');

UA()->timeout(5);
my $respond =ProbeRequest("/user/UserAdjustments.js");
if($respond!~ /^HTTP ERROR/) {
  $result{MODELID} = $1 if $respond =~ /var\s+strCardType\s*=\s*"(.+)";/i; #ex: var strCardType = "Raven-M";
}else {
  my ($err)= $respond=~/^HTTP ERROR \[(\d+)\]/;
  ProbeErr("PCE-0500","Device does not respond",$respond) if $err=~/^5\d\d/;
  ProbeErr("PCE-0401","Authorization error",    $respond) if $err==401;
}
ProbeErr("PCE-0030","Cannot get MODELID or FIRMWARE",$respond) if ! $result{MODELID};

# Check MODELID & FIRMWARE ---------------------------------------------------
if(defined $conf->{MODELID} and $result{MODELID} ne $conf->{MODELID}) {
  $result{STATUS}="WARNING: PCW-0001 [$conf->{DEVID}] MODELID does not match configuration";
}elsif(defined $conf->{CAMERAFIRMWARE} and $result{FIRMWARE} ne $conf->{CAMERAFIRMWARE}) {
  $result{STATUS}="WARNING: PCW-0001 [$conf->{DEVID}] FIRMWARE does not match configuration";
}

#------------------------------------------------------------------------------
# get Sample picture 
#------------------------------------------------------------------------------
if($conf->{PROBE} eq 'DEFINE') {
   $result{SNAPSHOT}=ProbeSamplePicture();
}

#------------------------------------------------------------------------------
# get video and audio properties
#------------------------------------------------------------------------------

# no code for MangoDSP

#------------------------------------------------------------------------------
# interim report & exit 
#------------------------------------------------------------------------------
ProbeResult(\%result)  if $conf->{PROBE} =~ /^(DEFINE|FAST)$/;
ProbeResult(\%result)  if $conf->{DEVID}==0;

#------------------------------------------------------------------------------
# set RC (rate control) parameters + qality + imagesize
#------------------------------------------------------------------------------
$respond=ProbeRequest("/user/AnalogVideoSettings.xml");
if($respond=~/error/i) {
  ProbeErr("PCE-0040","Cannot retrieve analog video settings",$respond);
}
my $ref=new XML::Simple;
my $data=$ref->XMLin($respond,KeyAttr=>[]);#, KeepRoot => 1);
my $xml_out=qq(<?xml version="1.0" encoding="ISO-8859-1" ?>
<?xml-stylesheet type="text/xsl" href="AnalogVideoSettings.xsl"?>
<AnalogVideoSettings id="AnalogVideoSettings">\n);

foreach my $channel (@{$data->{Channel}})
{
    if ($channel->{value} == $conf->{CAMERA})
    {
        $channel->{VideoStandard}->{value} = $conf->{VSTANDARD};
        $channel->{Brightness}->{value}    = $conf->{BRIGHTNESS};
        $channel->{Contrast}->{value}      = $conf->{CONTRAST};
        $channel->{Color}->{value}         = $conf->{COLOR};
    }

    # recreating Channels nodes
    # Basically it can be done using XML::Simple, but it does not work correct with nodes sequence
    
    $xml_out .= qq(<Channel value="$channel->{value}" id="Channel">
                        <VideoStandard  id="VideoStandard"  value="$channel->{VideoStandard}->{value}"/>
                        <ConnectionType id="ConnectionType" value="$channel->{ConnectionType}->{value}"/>
                        <VideoOut       id="VideoOut"       checked="$channel->{VideoOut}->{checked}"/>
                        <Brightness     id="Brightness"     value="$channel->{Brightness}->{value}"/>
                        <Contrast       id="Contrast"       value="$channel->{Contrast}->{value}"/>
                        <Color          id="Color"          value="$channel->{Color}->{value}"/>
                       <Hue             id="Hue"            value="$channel->{Hue}->{value}"/>
                   </Channel>\n);
}
$xml_out .= "</AnalogVideoSettings>";
$respond=ProbeRequest("/user/AnalogVideoSettings.cgi",'POST',["Content-Type","application/xml; charset=UTF-8"],$xml_out);
if($respond=~/error/i) {
  ProbeErr("PCE-0040","Cannot update video settings",$respond);
}

if ($result{MODELID} =~/Raven-M/i) {
    # Finally, setup default ImageSize and Framerate for camera
    sleep 1;
    $respond=ProbeRequest("/user/VideoStreamingParams.xml");
    if($respond=~/error/i) {
	ProbeErr("PCE-0040","Cannot retrieve video streaming params",$respond);
    }
    $data=$ref->XMLin($respond,KeyAttr=>[]);#, KeepRoot => 1);

    # Compute FramerateFivisor value
    my @divisor_vals = (1,2,3,4,5,6,8,10,12,15,16,20,24,25,30);
    my $fr = $conf->{FRAMERATE};
    my $fr_divisor = int(30 / $fr);
    if ($fr > 30) {
	$fr_divisor = 1;
    }
    elsif ($fr < 1) {
	$fr_divisor = 30;
    }
    else {
	for (my $i = 0; $i < @divisor_vals; $i++) {
	    my $cur  = $divisor_vals[$i];
	    my $next = $divisor_vals[$i+1];
	    last if $cur == $fr_divisor;
    	    if ($fr_divisor > $cur && $fr_divisor < $next) {
		$fr_divisor = $cur;
	        last;
	    }
	}
    }
    
    $xml_out=qq(<?xml version="1.0" encoding="ISO-8859-1" ?>
<?xml-stylesheet type="text/xsl" href="VideoStreamingParams.xsl"?>
<VideoStreamingParams id="VideoStreamingParams">\n);

    foreach my $channel (@{$data->{Channel}})
    {
	if ($channel->{value} == $conf->{CAMERA})
	{
    	    $channel->{ImageSize}->{value} = $conf->{IMAGESIZE};
	    $channel->{FrameRateDivisor}->{value}    = $fr_divisor;
	}

	# recreating Channels nodes
        # Basically it can be done using XML::Simple, but it does not work correct with nodes sequence
    
	$xml_out .= qq(<Channel value="$channel->{value}" id="Channel">
                        <ImageSize  id="ImageSize"  value="$channel->{ImageSize}->{value}"/>
                        <FrameRateDivisor id="FrameRateDivisor" value="$channel->{FrameRateDivisor}->{value}"/>
                   </Channel>\n);
    }
    $xml_out .= "</VideoStreamingParams>";
    
    $respond=ProbeRequest("/user/VideoStreamingParams.cgi",'POST',["Content-Type","application/xml; charset=UTF-8"],$xml_out);
    if($respond=~/error/i) {
     ProbeErr("PCE-0040","Cannot update video streaming params",$respond);
    }
} # END If (Raven-M)

$result{RC_SET}="OK";
#------------------------------------------------------------------------------
# set AudioParams
#------------------------------------------------------------------------------
if ( $conf->{AUDIO} eq 'on' ) { 
# no code for MangoDSP
}
# final report-----------------------------------------------------------------------
ProbeResult(\%result);

